scriptName "fn_exportCfgFunctions_POSEIDON";
/*
	Author: Tom_48_97

	Description:
	Export functions list for Poseidon
	http://poseidon.arma3.fr

	Parameter(s):
		None

	Returns:
	NOTHING
*/
#define __filename "fn_exportCfgFunctions_POSEIDON"
#define writeRPT(VALUE) diag_log [format ["%1:LOG", __filename], format ["%1", VALUE]]

startloadingscreen [""];
private ["_text","_list"];
writeRPT("BEGIN");
_list = [];
_text = "";
_br = tostring [13,10];
{
	_child = configname _x;
	{
		_childChild = configname _x; /* :-P */
		{
			[_list,configname _x] call bis_fnc_arrayPush;
			diag_log format ["		{'trigger': 'bis_fnc_%1', 'contents': 'bis_fnc_%1'},",configname _x];
		} forEach ((configfile >> "cfgFunctions" >> _child >> _childChild) call bis_fnc_returnchildren);
	} forEach ((configfile >> "cfgFunctions" >> _child) call bis_fnc_returnchildren);
} forEach ((configfile >> "cfgFunctions") call bis_fnc_returnchildren);
_text = _text + "(";
{
	_text = _text + format ["bis_fnc_%1|",_x];
} forEach _list;
_text = _text + ")";
copyToClipboard _text;
writeRPT("END");
endloadingscreen;